20 files changed, 1670 insertions, 0 deletions
diff --git a/COPYING b/COPYING
new file mode 100644
index 0000000..6e10388
--- /dev/null
+++ b/COPYING
@@ -0,0 +1,6 @@
+# Xerl (c) 2005-2011, 2013 Dipl.-Inform. (FH) Paul C. Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same 
+# terms as Perl itself.
diff --git a/TODO b/TODO
new file mode 100644
index 0000000..1c8dc5c
--- /dev/null
+++ b/TODO
@@ -0,0 +1,5 @@
+Hint: Run 'make todo' (in the source tree) to see everything in every file what
+is to do!
+
+TODO: - Evaluate Template Toolkit, maybe use it
+TODO: - Documentation of all features/options 
diff --git a/Xerl.pm b/Xerl.pm
new file mode 100644
index 0000000..fd1421e
--- /dev/null
+++ b/Xerl.pm
@@ -0,0 +1,63 @@
+# Xerl (c) 2005-2011, 2013-2015, 2017 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+#use CGI::Carp 'fatalsToBrowser';
+use Time::HiRes 'gettimeofday';
+
+use Xerl::Base;
+use Xerl::Main::Global;
+use Xerl::Page::Document;
+use Xerl::Page::Templates;
+use Xerl::Setup::Configure;
+use Xerl::Setup::Parameter;
+use Xerl::Setup::Request;
+
+sub run {
+  my Xerl $self = $_[0];
+  my $time = [gettimeofday];
+
+  my $request = Xerl::Setup::Request->new( request => $ENV{REQUEST_URI} );
+  $request->parse();
+
+  my $config = Xerl::Setup::Configure->new(
+    config => $self->get_config(),
+    %$request
+  );
+  $config->parse();
+
+  return undef if $config->finish_request_exists();
+
+  $config->defaults();
+
+  my $parameter = Xerl::Setup::Parameter->new( config => $config );
+  $parameter->parse();
+  return undef if $config->finish_request_exists();
+
+  if ( $config->document_exists() ) {
+    my $document = Xerl::Page::Document->new( config => $config );
+    $document->parse();
+    return undef if $config->finish_request_exists();
+
+  }
+  else {
+    my $templates = Xerl::Page::Templates->new( config => $config );
+    $templates->parse();
+    return undef if $config->finish_request_exists();
+    $templates->print($time);
+  }
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/Base.pm b/Xerl/Base.pm
new file mode 100644
index 0000000..9ecd3bc
--- /dev/null
+++ b/Xerl/Base.pm
@@ -0,0 +1,122 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package UNIVERSAL;
+
+use strict;
+use warnings;
+
+use 5.14.0;
+
+use Data::Dumper;
+
+sub new {
+  my $self = shift;
+
+  bless {@_} => $self;
+}
+
+sub setval {
+  my UNIVERSAL $self = $_[0];
+
+  $self->{ $_[1] } = $_[2];
+
+  return undef;
+}
+
+sub getval {
+  my UNIVERSAL $self = $_[0];
+
+  return defined $self->{ $_[1] } ? $self->{ $_[1] } : '';
+}
+
+sub exists {
+  my UNIVERSAL $self = $_[0];
+
+  return exists $self->{ $_[1] } ? 1 : 0;
+}
+
+sub AUTOLOAD {
+  my UNIVERSAL $self = $_[0];
+  my $auto = our $AUTOLOAD;
+
+  return $self if $auto =~ /DESTROY/;
+
+  if ( $auto =~ /.*::set_(.+)$/ ) {
+    $self->{$1} = $_[1];
+
+  }
+  elsif ( $auto =~ /.*::set$/ ) {
+    $self->{ $_[1] } = $_[2];
+
+  }
+  elsif ( $auto =~ /.*::get_(.+)_ref$/ ) {
+    return defined $self->{$1} ? \$self->{$1} : [''];
+
+  }
+  elsif ( $auto =~ /.*::get_(.+)$/ ) {
+    return defined $self->{$1} ? $self->{$1} : '';
+
+  }
+  elsif ( $auto =~ /.*::undef_(.+)$/ ) {
+    return '' unless defined $self->{$1};
+
+    my $retval = $self->{$1};
+    undef $self->{$1};
+    return $retval;
+
+  }
+  elsif ( $auto =~ /.*::append_(.+)$/ ) {
+    if ( defined $self->{$1} ) {
+      $self->{$1} .= $_[1];
+
+    }
+    else {
+      $self->{$1} = $_[1];
+    }
+
+  }
+  elsif ( $auto =~ /.*::push_(.+)$/ ) {
+    if ( exists $self->{$1} ) {
+      push @{ $self->{$1} }, $_[1];
+
+    }
+    else {
+      $self->{$1} = [ $_[1] ];
+    }
+
+  }
+  elsif ( $auto =~ /.*::first_(.+)$/ ) {
+    return exists $self->{$1} ? ${ $self->{$1} }[0] : '';
+
+  }
+  elsif ( $auto =~ /.*::(.+)_exists$/ ) {
+    return exists $self->{$1} ? 1 : 0;
+
+  }
+  elsif ( $auto =~ /.*::(.+)_length$/ ) {
+    return ( ref $self->{$1} eq 'ARRAY' ) ? scalar @{ $self->{$1} } : 0;
+
+  }
+  elsif ( $auto =~ /.*::(.+)_isset$/ ) {
+    return exists $self->{$1} ? $self->{ $_[0] } : 0;
+
+  }
+  elsif ( $auto =~ /.*::dumper$/ ) {
+    say Dumper @_;
+    return undef;
+
+  }
+  else {
+    say "$auto is not a method of $self or UNIVERSAL";
+  }
+
+  return $self;
+}
+
+1;
+
diff --git a/Xerl/Main/Global.pm b/Xerl/Main/Global.pm
new file mode 100644
index 0000000..f5958d6
--- /dev/null
+++ b/Xerl/Main/Global.pm
@@ -0,0 +1,83 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Main::Global;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+sub SHUTDOWN {
+  exit 0;
+
+  # Never reach this point
+  return undef;
+}
+
+sub DEBUG {
+  say "Debug::@_";
+
+  return undef;
+}
+
+sub ERROR {
+  print "Content-Type: text/plain\n\nXerl runtime error: ",
+    join( ' ', time, @_ );
+
+  Xerl::Main::Global::SHUTDOWN();
+
+  # Never reach this point
+  return undef;
+}
+
+sub PLAIN {
+  print "Content-Type: text/plain\n\n";
+
+  DEBUG(@_) if @_;
+
+  return undef;
+}
+
+sub REDIRECT ($) {
+  my $location = shift;
+
+  say "Status: 301 Moved Permanantly";
+  print "Location: $location\n\n";
+
+  return undef;
+}
+
+sub HTTP {
+  my $descr = _HTTP_DESCR(shift);
+
+  print $descr;
+  local $, = ' ';
+  print $descr;
+
+  Xerl::Main::Global::SHUTDOWN();
+
+  # Never reach this point
+  return undef;
+}
+
+sub _HTTP_DESCR ($;$) {
+  my ( $status, $infomsg ) = @_;
+
+  $infomsg //= '';
+
+  # Sub returns one of the strings below
+  if ( $status == 404 ) {
+    "Status: 404 Not Found $infomsg\015\012\n\n"
+
+  }
+  else {
+    "Status: 405 Method not allowed $infomsg\015\012\n\n";
+  }
+}
+
+1;
diff --git a/Xerl/Page/Content.pm b/Xerl/Page/Content.pm
new file mode 100644
index 0000000..a5766ae
--- /dev/null
+++ b/Xerl/Page/Content.pm
@@ -0,0 +1,229 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Page::Content;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Data::Dumper;
+
+use Xerl::Base;
+use Xerl::Page::Rules;
+use Xerl::Setup::Configure;
+use Xerl::XML::Element;
+use Xerl::XML::Reader;
+
+use LWP::Simple;
+
+sub parse {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  my $xmlcontent = Xerl::XML::Reader->new(
+    path   => $config->get_templatepath(),
+    config => $config
+  );
+
+  if ( -1 == $xmlcontent->open() ) {
+    $config->set_finish_request(1);
+    return undef;
+  }
+
+  $xmlcontent->parse();
+
+  my $rules = Xerl::Page::Rules->new( config => $config );
+  $rules->parse( $config->get_xmlconfigrootobj() )
+    unless $config->exists('noparse');
+
+  $config->insertxmlvars( $config->get_xmlconfigrootobj() );
+  $self->insertrules( $rules, $xmlcontent->get_root() );
+
+  return undef;
+}
+
+sub insertrules {
+  my $self    = $_[0];
+  my $rules   = $_[1];
+  my $element = $_[2];
+
+  # Start inserting rules at <content>
+  $element = $element->starttag('content');
+
+  # If there is no <content>-tag, dont use a rule!
+  return unless defined $element;
+
+  my @content;
+  my $params = $element->get_params();
+
+  unshift @content, "Content-Type: $params->{type}\n\n"
+    if ref $params eq 'HASH' and exists $params->{type};
+
+  push @content, $self->_insertrules( $rules, $element );
+  $self->set_content( \@content );
+
+  return undef;
+}
+
+sub _insertrules {
+  my $self       = $_[0];
+  my $rules      = $_[1];
+  my $element    = $_[2];
+  my $config     = $self->get_config();
+  my $nonewlines = 0;
+
+  # Don't interate through the XML childs if we have a leaf node.
+  return () unless ref $element->get_array() eq 'ARRAY';
+  my ( $name, $rule, @content, $text, $params );
+
+  for my $succ ( @{ $element->get_array() } ) {
+    $name   = $succ->get_name();
+    $text   = $succ->get_text();
+    $params = $succ->get_params();
+
+    # Remove leading and ending whitespaces, also ending newlines.
+    $text =~ s/^ *(.*)( |\n)*$/$1/g;
+    unless ( ref( $rule = $rules->getval($name) ) eq 'ARRAY' ) {
+      if ( lc $name eq 'noop' ) {
+        if ( ref $succ->get_array() eq 'ARRAY' ) {
+          push @content, $self->_insertrules( $rules, $succ );
+
+        }
+        else {
+          push @content, "$text\n";
+        }
+
+      }
+      elsif ( lc $name eq 'tag' ) {
+        push @content, "<$text>\n";
+
+      }
+      elsif ( lc $name eq 'perl' ) {
+        push @content, '<perl>', $text, '</perl>';
+
+      }
+      elsif ( lc $name eq 'inject' ) {
+        # Fetch via LWP::Simple
+        #my $got = get($text);
+        # Bug in FreeBSD Perl and LWP Module
+        my $curl = $config->get_curlpath();
+        my $got = `$curl "$text"`;
+        if ($!) {
+          push @content, "$text: $!";
+        } else {
+          $got =~ s/</&lt;/g;
+          $got =~ s/>/&gt;/g;
+          push @content, $got;
+        }
+      }
+      elsif ( lc $name eq 'includerun' ) {
+        my $scriptpath = $config->get_contentpath() . $text;
+        my $io = Xerl::Tools::FileIO->new( path => $scriptpath );
+        $io->fslurp();
+        push @content, eval $io->str();
+
+      }
+      elsif ( lc $name eq 'navigation' ) {
+        my $menus = $config->get_menuobj()->get_array();
+
+        if ( ref $menus eq 'ARRAY' ) {
+          push @content, $self->_insertrules( $rules, $_ ) for @$menus;
+        }
+
+      }
+      else {
+
+        # No rule available, use the tag unmodified!
+        if ( $succ->get_single() ) {
+          push @content, "<$name" . ( $succ->params_str() || '' ) . " />\n"
+
+        }
+        else {
+          if ( $succ->get_flag_noendtag() == 1 ) {
+            push @content, "<$name" . ( $succ->params_str() || '' ) . ">\n";
+          }
+          else {
+            push @content,
+            "<$name" . ( $succ->params_str() || '' ) . '>',
+            $self->_insertrules( $rules, $succ ), $text, "</$name>\n";
+          }
+        }
+      }
+
+    }
+    else {
+
+      # Get a local copy of lrule, because orule may be modified.
+      # And then insert special vars if required:
+      #  @@text@@ => Text content of the current tag.
+
+      my $ruleparams = $rule->[2];
+      $nonewlines = 1 if exists $ruleparams->{nonewlines};
+
+      my ( $orule, $crule ) = ( $rule->[0], $rule->[1] );
+
+      $self->_insert_special_vars( $rules, $succ, \$orule );
+      $self->_insert_special_vars( $rules, $succ, \$crule );
+      chomp $orule;
+
+      # Parse for known tag params.
+      if ( ref $params eq 'HASH' ) {
+        Xerl::Page::Templates::PARSELINE( $config, '%%', \$text );
+
+        # <tag basename='yes'>path/to/file.bla</tag> => <tag>file.bla</tag>
+        $text =~ s#.*/(.*)$#$1# if lc $params->{basename} eq 'yes';
+
+        # <tag cut='?'>foo.bar.tld?options</tag> => <tag>?options</tag>
+        if ( exists $params->{cut} ) {
+          my $cut = quotemeta $params->{cut};
+          $text =~ s/.*$cut(.*)$/$1/o;
+        }
+
+        $text .= $params->{addback}
+        if exists $params->{addback};
+        $text = $params->{addfront} . $text
+        if exists $params->{addfront};
+      }
+
+      my $oadd =
+      exists $ruleparams->{addfront}
+      ? '<' . $ruleparams->{addfront}
+      : '';
+
+      my $cadd =
+      exists $ruleparams->{addback} ? $ruleparams->{addback} . '>' : '';
+
+      push @content, $orule, $oadd, $self->_insertrules( $rules, $succ ),
+      $text, $cadd, $crule;
+    }
+  }
+
+  return $nonewlines ? map { s/\n/ /go; $_ } @content : @content;
+}
+
+sub _insert_special_vars {
+  my $self    = $_[0];
+  my $rules   = $_[1];
+  my $element = $_[2];
+  my $rtext   = $_[3];
+  my $config  = $self->get_config();
+
+  $$rtext =~ s/@\@text\@\@/$_=$element->get_text();chomp;$_/geo;
+  $$rtext =~ s/@\@ln\@\@//go;
+
+  if ( $$rtext =~ /@\@(.*?)\@\@/ ) {
+    my $params = $element->get_params();
+    return unless ref $params eq 'HASH';
+    $$rtext =~ s/@\@(.*?)\@\@/$params->{$1}||''/geo;
+  }
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/Page/Document.pm b/Xerl/Page/Document.pm
new file mode 100644
index 0000000..4ba1c0b
--- /dev/null
+++ b/Xerl/Page/Document.pm
@@ -0,0 +1,55 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Page::Document;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Main::Global;
+use Xerl::Setup::Configure;
+use Xerl::Tools::FileIO;
+
+sub parse {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  return undef unless $config->document_exists();
+
+  my $document = $config->get_document();
+  my ($filename) = $document =~ m#([^/]+)$#;
+  my ($postfix)  = $document =~ /\.(.+)$/;
+  my $path;
+
+  print 'Content-Type: ';
+  print $config->getval( 'ctype.' . lc($postfix) ), "\n";
+  print "Content-Disposition: attachment; filename=\"$filename\"\n\n";
+
+  $path = $config->get_hostpath() . "/htdocs/$document";
+  unless ( -f $path ) {
+    $path =
+        $config->get_hostroot()
+      . $config->get_defaulthost()
+      . "/htdocs/$document";
+  }
+
+  my $io = Xerl::Tools::FileIO->new( path => $path );
+
+  if ( -1 == $io->fslurp() ) {
+    $config->set_finish_request(1);
+  }
+  else {
+    $io->print();
+  }
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/Page/Menu.pm b/Xerl/Page/Menu.pm
new file mode 100644
index 0000000..b18a7d7
--- /dev/null
+++ b/Xerl/Page/Menu.pm
@@ -0,0 +1,114 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Page::Menu;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Setup::Configure;
+use Xerl::Tools::FileIO;
+use Xerl::XML::Element;
+
+sub generate {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  my @site    = split /\//, $config->get_site();
+  my @compare = @site;
+  my $site    = pop @site;
+
+  my ( $content, $siteadd ) = ( 'content/', '' );
+
+  my $menuelem = $self->get_menu( $content, $siteadd, shift @compare );
+
+  $self->push_array($menuelem)
+    if $menuelem->first_array()->array_length() > 1;
+
+  for my $s (@site) {
+    $content .= "$s.sub/";
+    $siteadd .= "$s/";
+
+    $menuelem = $self->get_menu( $content, $siteadd, shift @compare );
+    $self->push_array($menuelem)
+      if $menuelem->first_array()->array_length() > 1;
+  }
+
+  return undef;
+}
+
+sub get_menu {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  my ( $content, $siteadd, $compare ) = ( @_[ 1 ... 2 ], lc $_[3] );
+  my $issubsection = $content =~ m{\.sub/$};
+  my $pattern = qr/\.(?:xml)|(?:sub)$/;
+
+  my $io = Xerl::Tools::FileIO->new(
+    path     => $config->get_hostpath() . $content,
+    basename => 1,
+  );
+
+  unless ( $io->exists() ) {
+    Xerl::Main::Global::REDIRECT( $config->get_404() );
+    $config->set_finish_request(1);
+  }
+
+  $io->dslurp();
+  my $dir = $io->get_array();
+
+  my ( @prec, @dir );
+  map {
+    if   (/^\d+\..+\./) { push @prec, $_ }
+    else                { push @dir,  $_ }
+    }
+    grep {
+         $_ !~ /^home\.xml$/i
+      && $_ !~ /\.feed\.xml$/i
+      && $_ !~ /\.hide\.xml$/i
+      && $_ !~ /\.inc\.pl$/i
+    } @$dir;
+
+  my $root = Xerl::XML::Element->new();
+  my $menu = Xerl::XML::Element->new();
+
+  $menu->set_name('menu');
+
+  for ( $issubsection ? ( @dir, @prec ) : ( 'home.xml', @dir, @prec ) ) {
+    my ($site) = /(.*)$pattern/o;
+
+    $site =~ s#\.$#/home#o;
+    $site =~ s/^\d+\.//;
+
+    my $linkname = $site;
+    $linkname =~ s/(?:\d+\.)?(.)/\U$1/o;
+    $compare .= '/' if $linkname =~ s#(.*/)[^/]+$#$1#;
+
+    my $item = Xerl::XML::Element->new(
+      params => { link => "?site=$siteadd$site" },
+      text   => $linkname
+    );
+
+    $compare =~ s/^(\d+\.)//;
+    $item->set_name(
+      lc $linkname eq lc $compare ? 'activemenuitem' : 'menuitem' );
+
+    $item->set_prev($menu);
+    $menu->push_array($item);
+  }
+
+  $root->push_array($menu);
+  $menu->set_prev($root);
+
+  return $root;
+}
+
+1;
diff --git a/Xerl/Page/Rules.pm b/Xerl/Page/Rules.pm
new file mode 100644
index 0000000..ba6bd8e
--- /dev/null
+++ b/Xerl/Page/Rules.pm
@@ -0,0 +1,75 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Page::Rules;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Setup::Configure;
+use Xerl::XML::Element;
+
+sub parse {
+  my $self    = $_[0];
+  my $element = $_[1];
+  my $config  = $self->get_config();
+
+  $element = $element->starttag2( 'rules', $config->get_outputformat() );
+  return unless defined $element;
+
+  # Open and close rules:
+  my ( $orule, $crule );
+
+  # For all available rules in config.xml
+  for my $rule ( @{ $element->get_array() } ) {
+    my $params = $rule->get_params();
+
+    $orule = $rule->get_text();
+    chomp $orule;
+
+    $orule =~ s/\[/</go;
+    $orule =~ s/\]/>/go;
+
+    unless (
+      ref $params eq 'HASH'
+      && ( lc $params->{end} eq 'yes'
+        || lc $params->{start} eq 'yes' )
+      )
+    {
+      $crule = join '><', reverse split /> *</, $orule;
+      $crule = "<$crule>";
+      $crule =~ s/<</</go;
+      $crule =~ s/>>/>/go;
+      $crule =~ s/</<\//go;
+      $crule =~ s/\n//go;
+      $crule =~ s/ .+?>/>/go;
+      $crule .= "\n";
+
+    }
+    else {
+      if ( lc $$params{start} eq 'yes' ) {
+        $crule = '';
+
+      }
+      else {
+        $crule = $orule;
+        $orule = '';
+      }
+      $crule .= "\n";
+    }
+
+    $params = {} unless ref $params eq 'HASH';
+    $self->setval( $rule->get_name(), [ "$orule\n", $crule, $params ] );
+  }
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/Page/Templates.pm b/Xerl/Page/Templates.pm
new file mode 100644
index 0000000..7827f3b
--- /dev/null
+++ b/Xerl/Page/Templates.pm
@@ -0,0 +1,218 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Page::Templates;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Time::HiRes 'tv_interval';
+use Digest::MD5;
+
+use Xerl::Base;
+use Xerl::Page::Content;
+use Xerl::Page::Menu;
+use Xerl::Setup::Configure;
+use Xerl::Tools::FileIO;
+
+use constant RECURSIVE => 1;
+
+sub parse {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  my $site = $config->get_site();
+
+  my $subpath = $site;
+  if ( $site =~ s#^.*/(.*)$#$1#o ) {
+    $subpath =~ s#/[^/]+$#/#;
+    $subpath =~ s#/#.sub/#go;
+
+  }
+  else {
+    $subpath = '';
+  }
+
+  my $cachefile =
+      $config->get_template() . ';'
+    . $config->get_outputformat() . ';'
+    . $site
+    . ( $config->noparse_exists() ? '.noparse' : '' )
+    . '.cache';
+
+  my $cachepath = $config->get_cachepath() . $subpath;
+
+  if ( -f $cachepath . $cachefile
+    && ( $config->usecache_exists() or not $config->nocache_exists() ) )
+  {
+
+    my $io = Xerl::Tools::FileIO->new( path => $cachepath . $cachefile );
+
+    if ( -1 == $io->fslurp() ) {
+      $config->set_finish_request(1);
+      return undef;
+    }
+
+    $self->set_array( $io->get_array() );
+
+  }
+  else {
+    my $xmlconfigpath = $config->get_hostpath() . 'config.xml';
+
+    $xmlconfigpath = $config->get_defaulthostpath() . 'config.xml'
+      unless -f $xmlconfigpath;
+
+    my $xmlconfigreader =
+      Xerl::XML::Reader->new( path => $xmlconfigpath, config => $config );
+
+    if ( -1 == $xmlconfigreader->open() ) {
+      $config->set_finish_request(1);
+      return undef;
+    }
+
+    $xmlconfigreader->parse();
+    $config->set_xmlconfigrootobj( $xmlconfigreader->get_root() );
+
+    my $menu = Xerl::Page::Menu->new( config => $config );
+    $menu->generate();
+    $config->set_menuobj($menu);
+
+    if ( $site =~ /^(\d+)\./ ) {
+      $config->set_templatepath(
+        $config->get_hostpath() . "content/$subpath$site.xml" );
+    }
+    elsif ( -f $config->get_hostpath() . "content/$subpath$site.xml" ) {
+      $config->set_templatepath(
+        $config->get_hostpath() . "content/$subpath$site.xml" );
+    }
+
+    # Hidden files
+    elsif ( -f $config->get_hostpath() . "content/$subpath.$site.xml" ) {
+      $config->set_templatepath(
+        $config->get_hostpath() . "content/$subpath.$site.xml" );
+    }
+    else {
+      my $glob = $config->get_hostpath() . "content/$subpath*.$site.xml";
+      eval "(\$glob) = sort <$glob>;";
+      $config->set_templatepath($glob);
+    }
+
+    my $bodycontent = Xerl::Page::Content->new( config => $config );
+    $bodycontent->parse();
+
+    my $templatepath =
+      $config->get_hostpath() . "templates/" . $config->get_template() . '.xml';
+
+    $templatepath =
+        $config->get_defaulthostpath()
+      . "templates/"
+      . $config->get_template() . '.xml'
+      unless -f $templatepath;
+
+    $config->set_templatepath($templatepath);
+
+    my $templatecontent = Xerl::Page::Content->new( config => $config );
+    $templatecontent->parse();
+
+    $self->set_array( $templatecontent->get_content() );
+    $config->set_content( $bodycontent->get_content() );
+    $self->parsetemplate( '%%', RECURSIVE );
+
+    my $io = Xerl::Tools::FileIO->new(
+      path     => $cachepath,
+      filename => $cachefile,
+      array    => $self->get_array(),
+    );
+
+    $io->fwrite();
+  }
+
+  $self->parsetemplate('$$');    # Parsing dynamic vars.
+  return undef;
+}
+
+sub parsetemplate {
+  my $self          = $_[0];
+  my $config        = $self->get_config();
+  my $deepnesslevel = $_[2] || 0;
+
+  return $self if $deepnesslevel == 100;
+
+  my ( $sep, $foundflag ) = quotemeta $_[1];
+
+  PARSELINE( $config, $sep, \$_, \$foundflag ) for @{ $self->get_array() };
+
+  return $self->parsetemplate( $_[1], $deepnesslevel + 1 )
+    if defined $deepnesslevel > 0 and $foundflag;
+
+  return undef;
+}
+
+sub print {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  my ( $code, $flag ) = ( '', 0 );
+  my $time  = $_[1];
+  my $hflag = 1;
+
+  for my $line ( @{ $self->get_array() } ) {
+    if ( $hflag == 1 && $config->exists('noparse') ) {
+      $line =~ s#^Content-Type.*#Content-Type: text/plain#i;
+      $hflag = 0;
+    }
+
+    $line =~ s/  +/ /g;
+    redo if !$flag and $line =~ s/<perl>((?:.|\n)*?)<\/perl>/eval $1/ego;
+
+    if ( !$flag and $line =~ s/<perl>(.*)$//o ) {
+      $code .= $1;
+      $flag = 1;
+
+    }
+    elsif ( $line =~ s/^(.*?)<\/perl>/eval $code.$1/eo ) {
+      ( $code, $flag ) = ( '', 0 );
+      redo;
+
+    }
+    elsif ($flag) {
+      $line =~ s/^(.*\n)$//o;
+      $code .= $1;
+      next;
+    }
+
+    my $time = defined $time ? sprintf '%1.4f', tv_interval($time) : '';
+
+    $line =~ s/!!HOSTNAME!!/$config->get_hostname()/ge;
+    $line =~ s/!!TIME!!/$time/ge;
+    $line =~ s/!!LT!!/</g;
+    $line =~ s/!!GT!!/>/g;
+    $line =~ s#!!URL\((.+?)\)!!#<a href="$1">$1</a>#g;
+
+    print $line;
+  }
+
+  return undef;
+}
+
+# Static sub
+sub PARSELINE($$$;$) {
+  my $config = $_[0];
+  my ( $sep, $line, $foundflag ) = @_[ 1 .. 3 ];
+
+  $$line =~ s/$sep(!)?(.+?)$sep/
+     defined $1 ? `$2` :
+       (ref $config->getval($2) eq 'ARRAY') 
+      ? join '', @{$config->getval($2)} :
+      $config->getval($2)/eg and $$foundflag = 1;
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/Setup/Configure.pm b/Xerl/Setup/Configure.pm
new file mode 100644
index 0000000..406df9c
--- /dev/null
+++ b/Xerl/Setup/Configure.pm
@@ -0,0 +1,169 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Setup::Configure;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Tools::FileIO;
+use Xerl::XML::Element;
+
+sub parse {
+  my $self = $_[0];
+  my $file = Xerl::Tools::FileIO->new( 'path' => $self->get_config() );
+
+  if ( -1 == $file->fslurp() ) {
+    $self->set_finish_request(1);
+    return undef;
+  }
+
+  my $re = qr/^(.+?) *=(.+?) *\n?$/;
+
+  for ( @{ $file->get_array() } ) {
+    next if /^\s*#/;
+    s/#.*//;
+
+    $self->setval( $1, $self->eval($2) ) if $_ =~ $re;
+  }
+
+  return $self;
+}
+
+sub defaults {
+  my $self = $_[0];
+
+  $self->set_proto('https') if exists $ENV{HTTPS};
+
+  $self->set_site( $self->get_defaultcontent() )
+    unless $self->site_exists();
+
+  $self->set_nsite( $self->get_site() =~ /^(?:\d*\.)?(.*)/ );
+
+  $self->set_template( $self->get_defaulttemplate() )
+    unless $self->template_exists();
+
+  $self->set_style( $self->get_defaultstyle() )
+    unless $self->style_exists();
+
+  $self->set_proto( $self->get_defaultproto() )
+    unless $self->proto_exists();
+
+  $self->set_host( lc $ENV{HTTP_HOST} )
+    unless $self->host_exists();
+
+  my ($hostname) = $ENV{HTTP_HOST} =~ /^([^\.]*)\./;
+
+  $self->set_hostname( lc $hostname )
+    unless $self->hostname_exists();
+
+  my $host = $self->get_host();
+  unless ( -d $self->get_hostroot() . $host ) {
+    my $alias = $self->get_hostroot() . 'alias:' . $host;
+    my $alias_host = '';
+
+    unless ( -f $alias ) {
+      my ($hostname, @domain) = split /\./, $host;
+      my $domain = join '.', @domain;
+      $alias = $self->get_hostroot() . 'alias:' . $domain;
+      $alias_host = "$hostname.";
+    }
+
+    if ( -f $alias ) {
+      my $file = Xerl::Tools::FileIO->new( 'path' => $alias );
+      $file->fslurp();
+      $alias_host .= $file->shift();
+
+      $self->set_host( $alias_host );
+    }
+
+    my $redirect = $self->get_hostroot() . 'redirect:' . $self->get_host();
+
+    if ( -f $redirect ) {
+      my $file = Xerl::Tools::FileIO->new( 'path' => $redirect );
+      $file->fslurp();
+
+      my $location = $file->shift();
+      Xerl::Main::Global::REDIRECT($location);
+      $self->set_finish_request(1);
+    }
+  }
+
+  $self->set_outputformat( $self->get_defaultoutputformat() )
+    unless $self->outputformat_exists();
+
+  if ( $self->format_exists() ) {
+    $self->set_outputformat( $self->get_format() );
+    $self->set_template( $self->get_format() );
+    $self->set_site( $self->get_format() );
+    $self->set_nocache(1)
+      if $self->get_format() =~ /\.feed$/;
+  }
+
+  $self->set_host( $self->getval( $self->get_host() ) )
+    if $self->exists( $self->get_host() );
+
+  $self->set_host( $self->getval( $self->get_host() ) )
+    if $self->exists( $self->get_host() );
+
+  my $request_subdir = $self->get_request_subdir();
+  $self->set_hostpath(
+    $self->get_hostroot() . $self->get_host() . $request_subdir . "/" );
+
+  $self->set_defaulthostpath(
+    $self->get_hostroot() . $self->get_defaulthost() . '/' );
+
+  $self->set_cachepath(
+    $self->get_cacheroot() . $self->get_host() . $request_subdir . '/' );
+
+  $self->set_htdocspath( $self->get_hostpath() . 'htdocs/' );
+
+  $self->set_templatespath( $self->get_hostpath() . 'templates/' );
+
+  $self->set_contentpath( $self->get_hostpath() . 'content/' );
+
+  $self->set_is_ipv6( $ENV{REMOTE_ADDR} =~ /:/ ? 1 : 0 );
+
+  return undef;
+}
+
+sub eval {
+  my $self = $_[0];
+  my $val  = $_[1];
+
+  $val =~ s/^!(.+)/`$1`/eo;
+
+  return $val;
+}
+
+sub insertxmlvars {
+  my $self    = $_[0];
+  my $element = $_[1];
+
+  $element = $element->starttag('variables');
+
+  return $self
+    unless defined $element
+      or $element->get_array() eq 'ARRAY';
+
+  my $text;
+  for ( @{ $element->get_array() } ) {
+    $text = $_->get_text();
+    chomp $text;
+
+    $text =~ s/%%(.*?)%%/$self->getval($1)/eg;
+    $self->setval( $_->get_name(), $text );
+  }
+
+  return $self;
+}
+
+1;
+
diff --git a/Xerl/Setup/Parameter.pm b/Xerl/Setup/Parameter.pm
new file mode 100644
index 0000000..8d1c019
--- /dev/null
+++ b/Xerl/Setup/Parameter.pm
@@ -0,0 +1,50 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Setup::Parameter;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Main::Global;
+use Xerl::Setup::Configure;
+use Xerl::Tools::FileIO;
+
+sub parse {
+  my $self   = $_[0];
+  my $config = $self->get_config();
+
+  print "Content-Type: text/plain\n\n"
+    if $config->plain_exists();
+
+  if ( $config->href_exists() ) {
+    print "Location: ", $config->get_href(), "\n\n";
+    $config->set_finish_request(1);
+  }
+  elsif ( $config->env_exists() ) {
+    print "Content-Type: text/plain\n\n";
+    print "$_=", $ENV{$_}, "\n" for keys %ENV;
+    $config->set_finish_request(1);
+  }
+
+  if ( $config->devel_exists() ) {
+    $config->set_nocache(1);
+  }
+
+  if ( $config->conf_exists() ) {
+    print "Content-Type: text/plain\n\n";
+    print "$_=", $config->{$_}, "\n" for keys %$config;
+    $config->set_finish_request(1);
+  }
+
+  return $self;
+}
+
+1;
diff --git a/Xerl/Setup/Request.pm b/Xerl/Setup/Request.pm
new file mode 100644
index 0000000..e20eaa4
--- /dev/null
+++ b/Xerl/Setup/Request.pm
@@ -0,0 +1,50 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Setup::Request;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+
+sub parse {
+  my $self    = $_[0];
+  my $request = $self->get_request();
+
+  # Secure it!
+  $request =~ s#/\.\.##g;
+
+  # Remove last /
+  $request =~ s#/$##;
+
+  my $request_subdir = $request;
+  $request_subdir =~ s#/\?.*##;
+  $self->set_request_subdir($request_subdir);
+
+  # List context returns $1
+  ($_) = $request =~ /\?(.+)/;
+
+  return $self unless defined;
+
+  my $params = '';
+
+  # List context uses ($1,$2) as method args
+  for ( split /&/ ) {
+    $self->setval(/(.+?)=(.+)/);
+    $params .= "&amp;$1=$2" if $1 ne 'site';
+  }
+
+  $self->set_params($params);
+
+  return undef;
+}
+
+1;
+
diff --git a/Xerl/Tools/FileIO.pm b/Xerl/Tools/FileIO.pm
new file mode 100644
index 0000000..45eb64b
--- /dev/null
+++ b/Xerl/Tools/FileIO.pm
@@ -0,0 +1,169 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::Tools::FileIO;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl::Base;
+use Xerl::Main::Global;
+
+sub dslurp {
+  my $self = $_[0];
+  my $path = $self->get_path();
+
+  $path .= '/' unless $path =~ /\/$/;
+  opendir my $dir, $path or Xerl::Main::Global::ERROR( $!, $path, caller() );
+
+  my @dir = sort
+    map  { $path . $_ }
+    grep { /^[^\.]/o } readdir($dir);
+
+  @dir = map { s#.*/([^/]+\..+)$#$1#o; $_ } @dir
+    if $self->basename_exists();
+
+  closedir $dir;
+  $self->set_array( \@dir );
+
+  return undef;
+}
+
+sub fslurp {
+  my $self = $_[0];
+  my $path = _SECUREPATH( $self->get_path() );
+
+  unless ( -f $path ) {
+    Xerl::Main::Global::HTTP( 404, "Not found: $path" );
+    return -1;
+  }
+
+  open my $file, $path or Xerl::Main::Global::ERROR( $!, $path, caller() );
+  flock $file, 2;
+
+  my @slurp = <$file>;
+
+  flock $file, 3;
+  close $file;
+
+  $self->set_array( \@slurp );
+
+  return 0;
+}
+
+sub exists {
+  my $self = $_[0];
+  my $path = _SECUREPATH( $self->get_path() );
+
+  return -e $path;
+}
+
+sub fwrite {
+  my $self = $_[0];
+  $self->_fwrite(0);
+
+  return undef;
+}
+
+sub fwriteappend {
+  my $self = $_[0];
+  $self->_fwrite(1);
+
+  return undef;
+}
+
+sub print {
+  my $self = $_[0];
+  print @{ $self->get_array() };
+
+  return undef;
+}
+
+sub reverse_array {
+  my $self = $_[0];
+
+  my @array = reverse @{ $self->get_array() };
+  $self->set_array( \@array );
+
+  return undef;
+}
+
+sub merge {
+  my ( $self, $other ) = @_;
+
+  my @merged = ( @{ $self->get_array() }, @{ $other->get_array() } );
+  my $fio = Xerl::Tools::FileIO->new();
+  $fio->set_array( \@merged );
+
+  return $fio;
+}
+
+sub shift {
+  my $self = $_[0];
+  chomp( my $shift = shift @{ $self->get_array() } );
+
+  return $shift;
+}
+
+sub pop {
+  my $self = $_[0];
+  chomp( my $pop = pop @{ $self->get_array() } );
+
+  return $pop;
+}
+
+sub str {
+  my $self = $_[0];
+  return join '', @{ $self->get_array() };
+}
+
+sub _fwrite {
+  my $self   = $_[0];
+  my $append = $_[1];
+
+  my ( $path, $filename ) =
+    ( _SECUREPATH( $self->get_path() ), _SECUREPATH( $self->get_filename() ) );
+
+  my $path_ = '';
+  for ( split /\//, $path ) {
+    $path_ .= $_ . '/';
+    mkdir $path_
+      or Xerl::Main::Global::ERROR( $!, $path_, caller() )
+      unless -d $path_;
+  }
+
+  my $f;
+  if ( $append == 0 ) {
+    open $f, ">$path$filename"
+      or Xerl::Main::Global::ERROR( $!, $path . $filename, caller() );
+
+  }
+  else {
+    open $f, ">>$path$filename"
+      or Xerl::Main::Global::ERROR( $!, $path . $filename, caller() );
+  }
+
+  flock $f, 2;
+  print $f @{ $self->get_array() };
+  flock $f, 3;
+  close $f;
+
+  return undef;
+}
+
+use overload '+' => \&merge;
+
+sub _SECUREPATH($) {
+  my $path = $_[0];
+  $path =~ s/\.\.+\/?//g;
+
+  return $path;
+}
+
+1;
diff --git a/Xerl/XML/Element.pm b/Xerl/XML/Element.pm
new file mode 100644
index 0000000..aadccec
--- /dev/null
+++ b/Xerl/XML/Element.pm
@@ -0,0 +1,48 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::XML::Element;
+
+use strict;
+use warnings;
+
+use Xerl::Base;
+
+sub starttag {
+  my $self = $_[0];
+  my ( $name, $temp ) = ( $_[1], undef );
+
+  return $self if $self->get_name() eq $name;
+  return undef if ref $self->get_array() ne 'ARRAY';
+
+  for ( @{ $self->get_array() } ) {
+    $temp = $_->starttag($name);
+    return $temp if defined $temp;
+  }
+
+  return undef;
+}
+
+sub starttag2 {
+  my $self = $_[0];
+  my ( $name, $after ) = @_[ 1 ... 2 ];
+
+  my $element = $self->starttag($name);
+  return $element->starttag($after) if defined $element;
+
+  return undef;
+}
+
+sub params_str {
+  my $self   = $_[0];
+  my $params = $self->get_params();
+
+  return undef if $params eq '';
+  return join '', map { " $_=\"" . $params->{$_} . '"' } keys %$params;
+}
+
+1;
diff --git a/Xerl/XML/Reader.pm b/Xerl/XML/Reader.pm
new file mode 100644
index 0000000..a744025
--- /dev/null
+++ b/Xerl/XML/Reader.pm
@@ -0,0 +1,45 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::XML::Reader;
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use XML::SAX;
+
+use Xerl::Base;
+use Xerl::XML::Element;
+use Xerl::XML::SAXHandler;
+
+sub open {
+  my $self = shift;
+
+  if ( -f $self->get_path() ) {
+    return 0;
+  }
+  else {
+    return 1;
+  }
+}
+
+sub parse {
+  my $self = shift;
+
+  XML::SAX->add_parser(q(XML::SAX::PurePerl));
+  my $sax_handler = Xerl::XML::SAXHandler->new();
+
+  my $parser = XML::SAX::ParserFactory->parser( Handler => $sax_handler );
+  $parser->parse_uri( $self->get_path() );
+  $self->set_root( $sax_handler->{xerl}{root} );
+
+  return undef;
+}
+
+1;
diff --git a/Xerl/XML/SAXHandler.pm b/Xerl/XML/SAXHandler.pm
new file mode 100644
index 0000000..69759ef
--- /dev/null
+++ b/Xerl/XML/SAXHandler.pm
@@ -0,0 +1,93 @@
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+package Xerl::XML::SAXHandler;
+
+use base qw(XML::SAX::Base);
+
+use strict;
+use warnings;
+
+use 5.14.0;
+
+use Data::Dumper;
+
+use Xerl::Base;
+use Xerl::XML::Element;
+
+sub start_document {
+  my ( $self, $doc ) = @_;
+
+  $self->{xerl}{root}    = undef;
+  $self->{xerl}{current} = undef;
+  $self->{xerl}{stack}   = [];
+
+  return undef;
+}
+
+sub start_element {
+  my ( $self, $doc ) = @_;
+  my $x = $self->{xerl};
+
+  if ( defined $x->{current} ) {
+    push @{ $x->{stack} }, $x->{current};
+    $x->{root} = $x->{current} unless defined $x->{root};
+  }
+
+  my %params = map { $_->{Name} => $_->{Value} } values %{ $doc->{Attributes} };
+
+ # Extract name and flags from a tag such as: <NAME.xerl.FLAG1.FLAG2.FLAGN...>..
+  my ( $name, @flags ) = _GET_NAME_N_FLAG( $doc->{Name} );
+
+  $x->{current} = Xerl::XML::Element->new();
+  $x->{current}->set_text('');
+  $x->{current}->set_name($name);
+  $x->{current}->set( "flag_$_", 1 ) for @flags;
+  $x->{current}->set_params( \%params ) if %params;
+
+  ${ $x->{stack} }[-1]->push_array( $x->{current} ) if @{ $x->{stack} };
+
+  return undef;
+}
+
+sub characters {
+  my ( $self, $doc ) = @_;
+  my $x = $self->{xerl};
+
+  my $data = $doc->{Data};
+  $data =~ s/!!LT!!/</g;
+  $data =~ s/!!GT!!/>/g;
+  $data =~ s/!!N!!/&/g;
+
+  $x->{current}{text} .= $data;
+
+  return undef;
+}
+
+sub end_element {
+  my ( $self, $doc ) = @_;
+  my $x = $self->{xerl};
+
+  $x->{current} = pop @{ $x->{stack} };
+
+  return undef;
+}
+
+sub _GET_NAME_N_FLAG ($) {
+  my $string = shift;
+
+  my ( $name, $flags ) = $string =~ /^(.+)\.xerl\.(.*)$/;
+
+  if ( defined $flags ) {
+    return ( $name, split( /\./, $flags ) );
+  }
+  else {
+    return ($string);
+  }
+}
+
+1;
diff --git a/index.fpl b/index.fpl
new file mode 100755
index 0000000..8ae6699
--- /dev/null
+++ b/index.fpl
@@ -0,0 +1,30 @@
+#!/usr/bin/perl
+
+# Xerl (c) 2005-2011, 2013-2015 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl;
+
+use FCGI;
+use Socket;
+use Sys::Hostname;
+
+my $host = hostname();
+my $config =
+  -e "xerldev.conf"
+  ? "xerldev.conf"
+  : ( -e "xerl-$host.conf" ? "xerl-$host.conf" : 'config.conf' );
+
+while ( FCGI::accept >= 0 ) {
+  my $xerl = Xerl->new( config => $config );
+  $xerl->run();
+}
diff --git a/index.pl b/index.pl
new file mode 100755
index 0000000..64ef02e
--- /dev/null
+++ b/index.pl
@@ -0,0 +1,27 @@
+#!/usr/local/bin/perl
+
+# Xerl (c) 2005-2011, 2013-2015, 2017 by Paul Buetow
+#
+# 	E-Mail: xerl@dev.buetow.org 	WWW: https://xerl.buetow.org
+#
+# This is free software, you may use it and distribute it under the same
+# terms as Perl itself.
+
+use strict;
+use warnings;
+
+use v5.14.0;
+
+use Xerl;
+
+use Socket;
+use Sys::Hostname;
+
+my $host = hostname();
+my $config =
+  -e "xerldev.conf"
+  ? "xerldev.conf"
+  : ( -e "xerl-$host.conf" ? "xerl-$host.conf" : 'config.conf' );
+
+my $xerl = Xerl->new( config => $config );
+$xerl->run();
diff --git a/xerl.conf b/xerl.conf
new file mode 100644
index 0000000..5c0cc0a
--- /dev/null
+++ b/xerl.conf
@@ -0,0 +1,19 @@
+#nocache=defined
+cacheroot=/usr/local/www/xerlcache/
+ctype.asc=text/plain
+ctype.css=text/css
+ctype.jpg=image/jpg 
+ctype.pdf=application/pdf 
+ctype.png=image/png 
+ctype.txt=text/plain
+ctype.xml=text/plain
+defaultcontent=home
+defaulthost=default
+defaultoutputformat=html5
+defaultproto=http
+defaultstyle=css3.css
+defaulttemplate=html5
+hidesubhome=1
+hostroot=/usr/local/www/xerlhosts/branches/stable/hosts/
+404=https://paul.buetow.org
+curlpath=/usr/local/bin/curl